Вход | Регистрация


СКД накладывает условия на таблицы по которым я и не просил

СКД накладывает условия на таблицы по которым я и не просил
Я
   Shur1cIT
 
19.09.16 - 12:19
Суть отчета такова, берем остатки по одной организации регистр "ПартииТоваровНаСкладахБухгалтерский учет", а себестоимость у производственной "ВыпускПродукцииБухгалтерскийУчет" отчет работает как надо если только пользователь не захочет поставить отбор по организации, как только ставит отбор то этот отбор применяеться ковсем таблицам отчета!!! пытался зеркалировать организацию скобками не помогает вопрос как лечить?


ВЫБРАТЬ
    ВыпускПродукцииБухгалтерскийУчетОбороты.Продукция КАК Номенклатура,
    ВыпускПродукцииБухгалтерскийУчетОбороты.СерияПродукции КАК СерияНоменклатуры,
    ВыпускПродукцииБухгалтерскийУчетОбороты.ХарактеристикаПродукции КАК ХарактеристикаНоменклатуры,
    СУММА(ВыпускПродукцииБухгалтерскийУчетОбороты.КоличествоОборот) КАК КоличествоВыпуск,
    СУММА(ВыпускПродукцииБухгалтерскийУчетОбороты.СтоимостьОборот) КАК СтоимостьВыпуск
ПОМЕСТИТЬ ВыпускПродукции
ИЗ
    РегистрНакопления.ВыпускПродукцииБухгалтерскийУчет.Обороты(
            {(&НачПериода)},
            {(&Период)},
            ,
            (Продукция, СерияПродукции, ХарактеристикаПродукции) В
                (ВЫБРАТЬ
                    Остатки.Номенклатура КАК Продукция,
                    Остатки.СерияНоменклатуры КАК СерияПродукции,
                    Остатки.ХарактеристикаНоменклатуры КАК ХарактеристикаПродукции
                ИЗ
                    Остатки КАК Остатки) {(Организация = &ОранизацииПроизводства)}) КАК ВыпускПродукцииБухгалтерскийУчетОбороты

СГРУППИРОВАТЬ ПО
    ВыпускПродукцииБухгалтерскийУчетОбороты.Продукция,
    ВыпускПродукцииБухгалтерскийУчетОбороты.СерияПродукции,
    ВыпускПродукцииБухгалтерскийУчетОбороты.ХарактеристикаПродукции
 
 
   Shur1cIT
 
1 - 19.09.16 - 12:20
{(Организация = &ОранизацииПроизводства)}) в параметрах жестко прописывал организацию
   aleks_default
 
2 - 19.09.16 - 12:25
"пользователь не захочет поставить отбор по организации" -
а нахрена пользователь это делает?
   Shur1cIT
 
3 - 19.09.16 - 12:32
(2) В отчете имеються поля, в стандартном отчете можно на любое поле поставить отбор, ставя отбор на организацию видимо при формировании плана запроса или построении СКД "умный" компьютер считает что необходимо накладывать ограничения и на выборку причем на все таблици
   aleks_default
 
4 - 19.09.16 - 12:38
"Умный компьютер" не понял что ты от него хочешь. Или ты просто не смог ему объяснить неверно построив запрос.
   Shur1cIT
 
5 - 19.09.16 - 12:43
(4) Сам портянки с запрсом не люблю


ВЫБРАТЬ
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Организация,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Склад,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.ДокументОприходования,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Номенклатура,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.СерияНоменклатуры,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.ХарактеристикаНоменклатуры,
    СУММА(ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.КоличествоОстаток) КАК Количество,
    СУММА(ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.СтоимостьОстаток) КАК Стоимость
ПОМЕСТИТЬ Остатки
ИЗ
    РегистрНакопления.ПартииТоваровНаСкладахБухгалтерскийУчет.Остатки КАК ПартииТоваровНаСкладахБухгалтерскийУчетОстатки

СГРУППИРОВАТЬ ПО
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Организация,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Склад,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.ДокументОприходования,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.Номенклатура,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.СерияНоменклатуры,
    ПартииТоваровНаСкладахБухгалтерскийУчетОстатки.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    СебестоимостьПоФинансовойПремииОбороты.ДокументОприходования,
    СебестоимостьПоФинансовойПремииОбороты.Номенклатура,
    СебестоимостьПоФинансовойПремииОбороты.СерияНоменклатуры,
    СебестоимостьПоФинансовойПремииОбороты.ХарактеристикаНоменклатуры,
    СУММА(СебестоимостьПоФинансовойПремииОбороты.КоличествоОборот) КАК КоличествоПоПремии,
    СУММА(СебестоимостьПоФинансовойПремииОбороты.СтоимостьОборот) КАК СтоимостьПоПремии
ПОМЕСТИТЬ Премии
ИЗ
    РегистрНакопления.СебестоимостьПоФинансовойПремии.Обороты(
            {(&НачПериода)},
            {(&период)},
            ,
            (ДокументОприходования, Номенклатура, СерияНоменклатуры, Характеристиканоменклатуры) В
                (ВЫБРАТЬ
                    Остатки.ДокументОприходования КАК ДокументОприходования,
                    Остатки.Номенклатура КАК Номенклатура,
                    Остатки.СерияНоменклатуры КАК СерияНоменклатуры,
                    Остатки.ХарактеристикаНоменклатуры КАК Характеристиканоменклатуры
                ИЗ
                    Остатки КАК Остатки)) КАК СебестоимостьПоФинансовойПремииОбороты

СГРУППИРОВАТЬ ПО
    СебестоимостьПоФинансовойПремииОбороты.ДокументОприходования,
    СебестоимостьПоФинансовойПремииОбороты.Номенклатура,
    СебестоимостьПоФинансовойПремииОбороты.СерияНоменклатуры,
    СебестоимостьПоФинансовойПремииОбороты.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    ВыпускПродукцииБухгалтерскийУчетОбороты.Продукция КАК Номенклатура,
    ВыпускПродукцииБухгалтерскийУчетОбороты.СерияПродукции КАК СерияНоменклатуры,
    ВыпускПродукцииБухгалтерскийУчетОбороты.ХарактеристикаПродукции КАК ХарактеристикаНоменклатуры,
    СУММА(ВыпускПродукцииБухгалтерскийУчетОбороты.КоличествоОборот) КАК КоличествоВыпуск,
    СУММА(ВыпускПродукцииБухгалтерскийУчетОбороты.СтоимостьОборот) КАК СтоимостьВыпуск
ПОМЕСТИТЬ ВыпускПродукции
ИЗ
    РегистрНакопления.ВыпускПродукцииБухгалтерскийУчет.Обороты(
            {(&НачПериода)},
            {(&Период)},
            ,
            (Продукция, СерияПродукции, ХарактеристикаПродукции) В
                (ВЫБРАТЬ
                    Остатки.Номенклатура КАК Продукция,
                    Остатки.СерияНоменклатуры КАК СерияПродукции,
                    Остатки.ХарактеристикаНоменклатуры КАК ХарактеристикаПродукции
                ИЗ
                    Остатки КАК Остатки) {(Организация В (&ОранизацииПроизводства))}) КАК ВыпускПродукцииБухгалтерскийУчетОбороты

СГРУППИРОВАТЬ ПО
    ВыпускПродукцииБухгалтерскийУчетОбороты.Продукция,
    ВыпускПродукцииБухгалтерскийУчетОбороты.СерияПродукции,
    ВыпускПродукцииБухгалтерскийУчетОбороты.ХарактеристикаПродукции
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    Остатки.Организация,
    Остатки.Склад,
    Остатки.ДокументОприходования,
    Остатки.Номенклатура,
    Остатки.СерияНоменклатуры,
    Остатки.ХарактеристикаНоменклатуры,
    Остатки.Количество,
    ВЫБОР
        КОГДА ВыпускПродукции.КоличествоВыпуск > 0
            ТОГДА ВыпускПродукции.СтоимостьВыпуск / ВыпускПродукции.КоличествоВыпуск * Остатки.Количество
        ИНАЧЕ ВЫБОР
                КОГДА Премии.КоличествоПоПремии > 0
                    ТОГДА Премии.СтоимостьПоПремии / Премии.КоличествоПоПремии * Остатки.Количество + Остатки.Стоимость
                ИНАЧЕ Остатки.Стоимость
            КОНЕЦ
    КОНЕЦ КАК Остаток
ПОМЕСТИТЬ ИтоговаяТаблица
ИЗ
    Остатки КАК Остатки
        ЛЕВОЕ СОЕДИНЕНИЕ Премии КАК Премии
        ПО Остатки.ДокументОприходования = Премии.ДокументОприходования
            И Остатки.Номенклатура = Премии.Номенклатура
            И Остатки.СерияНоменклатуры = Премии.СерияНоменклатуры
            И Остатки.ХарактеристикаНоменклатуры = Премии.ХарактеристикаНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ ВыпускПродукции КАК ВыпускПродукции
        ПО Остатки.Номенклатура = ВыпускПродукции.Номенклатура
            И Остатки.СерияНоменклатуры = ВыпускПродукции.СерияНоменклатуры
            И Остатки.ХарактеристикаНоменклатуры = ВыпускПродукции.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    ИтоговаяТаблица.Организация,
    ИтоговаяТаблица.Склад,
    ИтоговаяТаблица.ДокументОприходования,
    ИтоговаяТаблица.Номенклатура,
    ИтоговаяТаблица.СерияНоменклатуры,
    ИтоговаяТаблица.ХарактеристикаНоменклатуры,
    ИтоговаяТаблица.Количество,
    ИтоговаяТаблица.Остаток
ИЗ
    ИтоговаяТаблица КАК ИтоговаяТаблица
   Shur1cIT
 
6 - 19.09.16 - 12:46
(4) соответственно пользователь работает с полями

ИтоговаяТаблица.Организация,
    ИтоговаяТаблица.Склад,
    ИтоговаяТаблица.ДокументОприходования,
    ИтоговаяТаблица.Номенклатура,
    ИтоговаяТаблица.СерияНоменклатуры,
    ИтоговаяТаблица.ХарактеристикаНоменклатуры,
    ИтоговаяТаблица.Количество,
    ИтоговаяТаблица.Остаток
ИЗ
    ИтоговаяТаблица КАК ИтоговаяТаблица


и накладывает отбор на ИтоговаяТаблица.Организация

в результате как я предпологаю это условие применяеться ко всем запросам, а не на готовую выборку "ИтоговаяТаблица"
   aleks_default
 
7 - 19.09.16 - 12:47
Дя я не о том. 
Галку проставь в ограничение поля "Условие"
   Shur1cIT
 
8 - 19.09.16 - 12:54
(7) поставил, напротив "ОрганизацииПроизводства"
при выборе на вкладке отбор организации точно такаеже ситуация...
   Shur1cIT
 
9 - 19.09.16 - 12:54
(8) пользователь Организацию не в параметрах, а в отборе выбирает
   aleks_default
 
10 - 19.09.16 - 12:59
Причем тут параметры? Галку поставь, и поле в отборах вообще выбрать нельзя будет.
 
 Рекламное место пустует
   DailyLookingOnASunse
 
11 - 19.09.16 - 13:06
А если в параметрах вирт. таблицы написать Организация = Организация?
С датами я вот такой способ видел (НеЗаполнять - пустая дата):
    РегистрБухгалтерии.Хозрасчетный.ОборотыДтКт(
            {&НеЗаполнять},
            {&НеЗаполнять},
   MUXACb
 
12 - 19.09.16 - 13:17
(0) Не используйте Автозаполнение
   Shur1cIT
 
13 - 19.09.16 - 13:29
(11) с датами у меня тоже работает
 РегистрНакопления.СебестоимостьПоФинансовойПремии.Обороты(
            {(&НачПериода)},
            {(&период)}, 

(12) где автозаполнение отключаеться?
   MUXACb
 
14 - 19.09.16 - 13:39
(13) В схеме компоновки, в самом низу снимите флаг "Автозаполнение". Потом заходите в конструктор на закладку "Компоновка данных". Для всех временных таблиц укажите список возможных условий. Для результирующей таблицы дополнительно укажите список доступных полей
   Shur1cIT
 
15 - 19.09.16 - 13:40
(14) ЗАРАБОТАЛО спасибо))))

Список тем форума
Рекламное место пустует  Рекламное место пустует
Чтобы обнаруживать ошибки, программист должен иметь ум, которому доставляет удовольствие находить изъяны там, где, казалось, царят красота и совершенство.
Фредерик Брукс-младший
ВНИМАНИЕ! Если вы потеряли окно ввода сообщения, нажмите Ctrl-F5 или Ctrl-R или кнопку "Обновить" в браузере.
Тема не обновлялась длительное время, и была помечена как архивная. Добавление сообщений невозможно.
Но вы можете создать новую ветку и вам обязательно ответят!
Каждый час на Волшебном форуме бывает более 2000 человек.
Рекламное место пустует