Есть две таблицы - втНом вида (номенклатура, количество) и Регистр оборотов вида (номенклатура, стоимость, валюта, период).
Необходимо в запросе для каждой строки втНом получить из регистра одно-единственное значение, последнее на текущую дату. Предполагается использование ключевого слова ПЕРВЫЕ 1.

Для тестирования и наглядности составил текст для консоли запросов:
[
ВЫБРАТЬ
   *
ПОМЕСТИТЬ втНом
ИЗ
   (ВЫБРАТЬ "Ном1" КАК Номенклатура, 1 КАК Количество
   ОБЪЕДИНИТЬ ВСЕ
   ВЫБРАТЬ "Ном2", 2
   ОБЪЕДИНИТЬ ВСЕ
   ВЫБРАТЬ "Ном3", 4) КАК Тмп
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   *
ПОМЕСТИТЬ втРег
ИЗ
   (
       ВЫБРАТЬ "Ном1" КАК Номенклатура, 50 КАК Цена, "Рубли" КАК Валюта, ДАТАВРЕМЯ(2001,01,01,00,00,00) КАК Период
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном1", 30 , "Рубли", ДАТАВРЕМЯ(2002,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном2", 15 , "Евро", ДАТАВРЕМЯ(2002,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном2", 600 , "Рубли", ДАТАВРЕМЯ(2001,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном3", 70 , "Доллары", ДАТАВРЕМЯ(2001,01,01,00,00,00)
   ) КАК Тмп
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   табНом.Номенклатура КАК Номенклатура,табНом.Количество КАК Количество,0 КАК Цена,0 КАК Валюта,null КАК Период
       ИЗ втНом КАК табНом
Объединить все
ВЫБРАТЬ
   табРег.Номенклатура,0,табРег.Цена,табРег.Валюта,табРег.Период
       ИЗ втРег КАК табРег
]
Сейчас обе виртуальные таблицы выбираются последовательно, без условий (исключительно для наглядности тестовых данных).
Необходимо получить выборку вида:

Номенклатура    Количество    Цена    Валюта    Период
Ном1    1    30    Рубли    01.01.2002 0:00:00
Ном2    2    15    Евро    01.01.2002 0:00:00
Ном3    4    70    Доллары    01.01.2001 0:00:00

СКД может. а иначе - получить остаток на каждую дату во временную таблицу и соединять по периоду

>> получить остаток на каждую дату во временную таблицу и соединять по периоду
Если можно, измени пример запроса под приведенный пример.

ты таблицы виртуальные с временными не путаешь?

Прошу обратить внимание, что хотя в тестовом примере втРег небольшая, в реальности она громадная, а получить остаток было-бы в корне неверно для такого показателя как "Цена".
Поэтому предполагается наличие ключевого слова ПЕРВЫЕ 1, или того, чем можно максимально ограничить выборку.

(3) Путаю :)

Если есть модераторы - перефразируйте пожалуйста все "виртуальные таблицы" во "временные", в том числе - в заголовке темы.

ой,блин.

короче,

Выбрать
 Втрег.Номенклатура,
 ВтРег.Цена,
 ВтРег.Валюта,
 ВтРег.Период
Из
 ВтРег
 Внутреннее Соединение
 (Выбрать
   ВтРег.Номенклатура, Максимум(ВтРег.Период) Как ПенриодМаксимум
 Из ВтРег
 Группировать По ВтРег.Номенклатура) Как Вложенный По
 Втрег.Номенклатура = Вложенный.Номенклатура И ВтРег.Период = Вложенный.ПенриодМаксимум

а вообще - это типа как "срез последних"

Мысль понял. Спасибо.
Задача решена, но, насколько я понял, выбираются все данные ВтРег.

Хочу решить её самым оптимальным способом, без выборки всех данных втРег. Объясняя "на пальцах" - хочу для каждой строки втНом выполнить запрос к втРег, с условием вида

ВЫБРАТЬ ПЕРВЫЕ 1
   *
ИЗ ВтРег КАК табРег
ГДЕ
   табРег.Номенклатура = табНом.Номенклатура
УПОРЯДОЧИТЬ ПО
   Период УБЫВ

(9) т.е. ты думаешь, что один запрос

Выбрать
   ВтРег.Номенклатура, Максимум(ВтРег.Период) Как ПенриодМаксимум
 Из ВтРег
 Группировать По ВтРег.Номенклатура

медленнее, чем тысяча запросов (по количеству строк)?

Честно говоря, не знаю :)
Вообще, задачу можно решить таким образом?

(11) ну, написать хранимку в скуле - и вперед

в 1с же - СКД может, но медленнее, чем (7), потому как как раз много запросов будет

А что есть хранимка? :)

Кореллированный запрос в помощь!

(14) вот: Хранимая Процедура

(15) не во всяком скуле такое есть. в МС, например, только в 2005 появился. я даже, сломав мозг, сделал как-то вывод иерархии через 1с++ в стиле стандартных семерошных запросов

2 Fragster: Понял, огромное спасибо!
2 Ksandr: буду гуглить, тоже спасибо.

(0) как вариант.
1. по регистру делаешь выборку возвращающую номенклатуру и максимальную дату.
2. выборку и п.1. соединяешь с своим регистром по номенклатуре и дате.
в итоге полчишь значения для максимальной даты

(19) http://lurkmore.ru/слоупок

(7) так же

(20) уважаемый, это оскорбительное ругательство

(22) ???
«Слоупок — покемон водно-психического типа и является одним из первых покемонов («It first appeared in the Generation I games») Слоупок может эволюционировать либо в Slowbro, достигнув 37 уровня, либо в Slowking (который, к слову, известен как едва ли не умнейший из всех покемонов) с помощью специального предмета»

а вообще - я просто намекаю, что ветку неплохо бы читать

(17)(18)
Кстати да, не работает на файловом варианте

2 Ksandr: Я изначально пытался написать коррелированный запрос для решения этой задачи, но не смог понять как обратиться к значению Номенклатура.
Если использовать коррелированный запрос в условии - пожалуйста, все работает.
Ты не мог-бы написать пример для (0) с учетом (9)?

ВЫБРАТЬ
   ВтНом.Номенклатура,
   ВтНом.Количество,
   ВтРег.Номенклатура КАК Номенклатура1,
   ВтРег.Цена,
   ВтРег.Валюта,
   ВтРег.Период
ИЗ
   ВтНом КАК ВтНом
       ЛЕВОЕ СОЕДИНЕНИЕ ВтРег КАК ВтРег
       ПО ВтНом.Номенклатура = ВтРег.Номенклатура
           И (ВтРег.Период В
               (ВЫБРАТЬ ПЕРВЫЕ 1
                   ВтРег.Период
               ИЗ
                   ВтРег
               ГДЕ
                   ВтРег.Номенклатура = ВтНом.Номенклатура
               УПОРЯДОЧИТЬ ПО
                   ВтРег.Период УБЫВ))


ЗЫ. В ВтРег дублей по Номенклатура,Период не должно быть...

Вот! Это оно! Значит в условии соединения... Спасибо :)).

хм...

сделал замер на приличной выборке:

ВЫБРАТЬ
   ЦеныНоменклатуры.Период,
   ЦеныНоменклатуры.Номенклатура,
   ЦеныНоменклатуры.Цена
ПОМЕСТИТЬ Цены
ИЗ
   РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
ГДЕ
   ЦеныНоменклатуры.ТипЦен = &ТипЦен
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Цены.Период,
   Цены.Номенклатура,
   Цены.Цена
ПОМЕСТИТЬ Результат1
ИЗ
   Цены КАК Цены
ГДЕ
   Цены.Период В
           (ВЫБРАТЬ ПЕРВЫЕ 1
               ТЗЦены.Период
           ИЗ
               Цены КАК ТЗЦены
           ГДЕ
               ТЗЦены.Номенклатура = Цены.Номенклатура
           УПОРЯДОЧИТЬ ПО
               ТЗЦены.Период УБЫВ)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Цены.Период,
   Цены.Номенклатура,
   Цены.Цена
ПОМЕСТИТЬ Результат2
ИЗ
   Цены КАК Цены
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
           МАКСИМУМ(Цены.Период) КАК Период,
           Цены.Номенклатура КАК Номенклатура
       ИЗ
           Цены КАК Цены
       
       СГРУППИРОВАТЬ ПО
           Цены.Номенклатура) КАК ВложенныйЗапрос
       ПО Цены.Период = ВложенныйЗапрос.Период
           И Цены.Номенклатура = ВложенныйЗапрос.Номенклатура





результаты:

РезультатЗапроса    Название таблицы    Время подзапроса
ТаблицаЗначений    ЦЕНЫ    0,079
ТаблицаЗначений    РЕЗУЛЬТАТ1    87,812
ТаблицаЗначений    РЕЗУЛЬТАТ2    0,172

а если добавить индекс в таблицу "цены":

ИНДЕКСИРОВАТЬ ПО
   Номенклатура,
   Период

РезультатЗапроса    Название таблицы    Время подзапроса    Количество строк
ТаблицаЗначений    ЦЕНЫ    0,094    6 930
ТаблицаЗначений    РЕЗУЛЬТАТ1    0,375    2 084
ТаблицаЗначений    РЕЗУЛЬТАТ2    0,125    2 084

(30)
Во-1х, никто и не спорил, что медленнее будет...
Во-2х, в (27) вторая таблица не зря дважды указывается. Так что замерь вот это:

ВЫБРАТЬ
   Цены.Период,
   Цены.Номенклатура,
   Цены.Цена
ПОМЕСТИТЬ Результат1
ИЗ
   Цены КАК Цены
   Внутреннее Соединение Цены Как Цены1
    По Цены1.Номенклатура = Цены.Номенклатура
    И Цены1.Период = Цены.Период
    И Цены1.Период В
          (ВЫБРАТЬ ПЕРВЫЕ 1
               ТЗЦены.Период
           ИЗ
               Цены КАК ТЗЦены
           ГДЕ
               ТЗЦены.Номенклатура = Цены.Номенклатура
           УПОРЯДОЧИТЬ ПО
               ТЗЦены.Период УБЫВ)

однако, если сделать 2 поля ключевыми (номенклатура и тип цен), то индексы уже не помогают:

РезультатЗапроса    Название таблицы    Время подзапроса    Количество строк
ТаблицаЗначений    ЦЕНЫ    0,61    24 895
ТаблицаЗначений    РЕЗУЛЬТАТ1    375,203    10 851
ТаблицаЗначений    ВЛОЖЕННЫЙЗАПРОС    0,594    10 849
ТаблицаЗначений    РЕЗУЛЬТАТ2    0,406    10 851

вариант (27) очень сильно зависит от индексов и порядка условий, добился результата (результат1 - вложенный подзапрос "Выбрать первые", результат2 - внутреннее соединение с ВложенныйЗапрос)
РезультатЗапроса    Название таблицы    Время подзапроса
ТаблицаЗначений    ЦЕНЫ    0,406
ТаблицаЗначений    РЕЗУЛЬТАТ1    1,375
ТаблицаЗначений    ВЛОЖЕННЫЙЗАПРОС    0,328
ТаблицаЗначений    РЕЗУЛЬТАТ2    0,297

в общем случае - вариант (7) читается похуже, но при этом практически не зависит от индексов, порядка полей и прочего

(34) Ещё раз: никто не спорил. Даже наоборот.

Но стОит изменить условие задачи, как всё санет не так очевидно:
Допустим, нужна не только последняя, но и предпоследняя цена. В (27) это решается "Выбрать Первые 2", а в (7)?

(35) еще одно внутреннее соединение с условием Максимум(Период)...Где Период < ПериодМаксимум

да, к сожалению, не так элегантно, как хотелось бы, но влияние на скорость незначительно

Мой мозг плавает в океане блаженства...

Интересно, а если в таблицу добавить нумератор и использовать при отборе? Не будет-ли это быстрее чем индексирование периода?

Fragster, если не секрет, какой инструмент используешь для замеров времени выполнения подзапросов?

(37) консоль запросов с доработками Чистова (для просмотра временных таблиц), Воробьева(для показа имен этих самых таблиц) и меня (для как раз замера времени)

В итоге после получения выборки данных регистра, ограниченной нашим набором номенклатуры в втРег, я еще раз выбираю втРег примернос следующим образом:

[
Выбрать * ПОМЕСТИТЬ втРег2 ИЗ втРег как табРег
ГДЕ
(табРег.Номенклатура, табРег.Поле1, ... , табРег.ПолеN) В
(ВЫБРАТЬ ПЕРВЫЕ 1
тмп.Номенклатура, тмп.Поле1, ... , тмп.ПолеN
ИЗ втРег КАК тмп
ГДЕ тмп.Номенклатура = табРег.Номенклатура)
]

А затем уже использую втРег2 для объединения.

Соответственно, дополнительные поля ограничивающие выборку должны быть расположены в порядке убывания скорости отбора по ним (насколько я понимаю, индексированное поле > числовое поле > текстовое поле).

Поправьте, если не прав.

P.S. Поля 1-N нужны исключительно для уникальности строк выборки. Для достижения уникальности строк можно использовать ВЫБРАТЬ РАЗЛИЧНЫЕ при формировании первичной втРег.

Правда есть одна проблема...
При тестировании часто вылетает 1с с ошибкой MSSQL. Возможно, недоработка платформы 8.1.15.14.
Возможно, в файловом варианте такого не будет.

с какой ошибкой? подозреваю про 256 таблиц

Хотя нет, в абсолютно пустой базе в файловом режиме (без конфигурации) на тестовом примере (который в начале темы) вот такая ошибка:

Ошибка СУБД:
Ошибка SQL: Поле не найдено '#Td25d710822d34f418e974cc84069b5dc_Q_001_T_001._Q_006_F_000'
по причине:
Ошибка SQL: Поле не найдено '#Td25d710822d34f418e974cc84069b5dc_Q_001_T_001._Q_006_F_000'

Щас проверю на 8.2 и наверное буду репортить %))

(43) где-то накосячил. у меня на том же релизе работает

На 8.2 вообще по другому отрабатывает...
Видимо, изменили язык запросов, либо получает NULL и в итоге при сравнении всегда получает Истина.
В общем, вот текст запроса:

[
ВЫБРАТЬ
   *
ПОМЕСТИТЬ втНом
ИЗ
   (ВЫБРАТЬ "Ном1" КАК Номенклатура, 1 КАК Количество
   ОБЪЕДИНИТЬ ВСЕ
   ВЫБРАТЬ "Ном2", 2
   ОБЪЕДИНИТЬ ВСЕ
   ВЫБРАТЬ "Ном3", 4) КАК Тмп
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   *
ПОМЕСТИТЬ втРег
ИЗ
   (
       ВЫБРАТЬ "Ном1" КАК Номенклатура, 50 КАК Цена, "Рубли" КАК Валюта, ДАТАВРЕМЯ(2001,01,01,00,00,00) КАК Период
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном1", 30 , "Рубли", ДАТАВРЕМЯ(2002,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном2", 15 , "Евро", ДАТАВРЕМЯ(2002,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном2", 600 , "Рубли", ДАТАВРЕМЯ(2001,01,01,00,00,00)
       ОБЪЕДИНИТЬ ВСЕ
       ВЫБРАТЬ "Ном3", 70 , "Доллары", ДАТАВРЕМЯ(2001,01,01,00,00,00)
   ) КАК Тмп
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   *
ПОМЕСТИТЬ втРег2
ИЗ
   втРег КАК табРег
   ГДЕ    (табРег.Номенклатура, табРег.Цена, табРег.Валюта, табРег.Период) В
   (ВЫБРАТЬ ПЕРВЫЕ 1 тмп.Номенклатура, тмп.Цена, тмп.Валюта,тмп.Период    ИЗ втРег КАК тмп ГДЕ тмп.Номенклатура = табРег.Номенклатура)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   *
ИЗ
   втНом КАК ТабНом
       ПОЛНОЕ СОЕДИНЕНИЕ втРег2 КАК ТабРег2
       ПО ТабНом.Номенклатура = ТабРег2.Номенклатура
]

Где накосячил? :)))))))

(46) ...

ВЫБРАТЬ
   "Ном1" КАК Номенклатура,
   1 КАК Количество
ПОМЕСТИТЬ втНом

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном2",
   2

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном3",
   4
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   "Ном1" КАК Номенклатура,
   50 КАК Цена,
   "Рубли" КАК Валюта,
   ДАТАВРЕМЯ(2001, 1, 1, 0, 0, 0) КАК Период
ПОМЕСТИТЬ втРег

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном1",
   30,
   "Рубли",
   ДАТАВРЕМЯ(2002, 1, 1, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном2",
   15,
   "Евро",
   ДАТАВРЕМЯ(2002, 1, 1, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном2",
   600,
   "Рубли",
   ДАТАВРЕМЯ(2001, 1, 1, 0, 0, 0)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Ном3",
   70,
   "Доллары",
   ДАТАВРЕМЯ(2001, 1, 1, 0, 0, 0)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   втРег.Номенклатура,
   втРег.Цена,
   втРег.Валюта,
   втРег.Период
ИЗ
   втРег КАК втРег
ГДЕ
   втРег.Период В
           (ВЫБРАТЬ ПЕРВЫЕ 1
               тмп.Период
           ИЗ
               втРег КАК тмп
           ГДЕ
               втРег.Номенклатура = тмп.Номенклатура
           УПОРЯДОЧИТЬ ПО
               тмп.Период УБЫВ)

правда так проще?

Те-же яйца только в смятку :).
Для поставленной задачи - проще. И правильнее я-бы даже сказал.
Но для скорости всеравно потребуется первичная выборка. Чтобы не обращаться к реальным данным каждый раз, когда проверяется условие.
Номенклатура там лишняя конечно в условии, остальное может варьироваться в зависимости от измерений регистра, чтобы гарантировать уникальность записи.

Слушай, а как ты поля индексировал во временной таблице?

Все, туплю, нашел. :)