Есть файл xsd с схемой XML документа, в котором нужно выгружать справочник контрагентов в внешний ПП.
Подскажите где можно почитать инструкцию по использованию XDTO в 1С,
или где посмотреть простенький пример обхода этой схемы, для создания XML документа.
Спасибо

up

(0) П.С Белоусов, A.B. Oстроверх  "1С:Предприятие: от 8.0 к 8.1"

(2) под рукой нет...

http://itland.ru/forum//index.php?showtopic=21932&pid=107069&st=0&#entry107069

http://infostart.ru/forum/forum14/topic8770/

http://teron.ru/index.php?showtopic=341687

http://aitika.ru/otvety/2426-1c-v8-Ispolzovanie-XDTO-serilizatsii-pri-obmene-dannimi-mejdu-konfiguratsiyami

Там вроде описываются простенькие примеры!

Поиск по форуму уже не рулит?

(9) в каком веке ты живешь??? поиск по форуму уже не модно!!! :)

я как понимаю это XDTO помогает только при создании обмена в однородных конфигурациях?
У меня есть файл с xml - XSD который сформирован для данных совсем иной программы (XXX),
как эту схему XSD я могу приспособить для ускорения выгрузки данных в программу XXX ?
Или это уже легче делать просто прямым формированием XML файла?

up

//Создание фабрики из xsd
   Пути = Новый Массив();
   Пути.Добавить("C:\Conf.xsd");
   Фабрика = СоздатьФабрикуXDTO(Пути);
   
   
//Создание объекта XDTO имея фабрику, имя тип и пространство имен

   тип = ТекФабрикаXDTO.Тип(ПространствоИмен, имяТипа);
   ОбъектXDTO = ТекФабрикаXDTO.Создать(тип);
   
//Работа с объектом XDTO
ОбъектXDTO.ТакоеТоСвойство = 1;
ОбъектXDTO.ДругоеТоСвойство = "Привет";

//Выгрузка объекта в xml
Док = Новый ДокументDOM(ПространствоИмен,ИмяДокумента);
ЗаписьУзлов = Новый ЗаписьУзловDOM;
ЗаписьУзлов.Открыть(Док);

ТекФабрикаXDTO.ЗаписатьXML(ЗаписьУзлов,ОбъектXDTO,ИмяОбъектаВXML,ПространствоИмен);
ЗаписьУзлов.Закрыть();

ЗаписьДом = Новый ЗаписьDOM;
ЗаписьXML = Новый ЗаписьXML;
ЗаписьXML.УстановитьСтроку();
ЗаписьДом.Записать(Док,ЗаписьXML);
СтрокаXML = ЗаписьXML.Закрыть();

(13) спасибо..
пару вопросов:
Что такое ДокументDOM ?
и что должн опередаваться в ИмяДокумента?

<?xml version="1.0" encoding="UTF-8"?>
<v8msg:Message xmlns:v8msg="http://v8.1c.ru/messages">
   <v8msg:Header>
       <v8msg:ExchangePlan>TestExchange</v8msg:ExchangePlan>
       <v8msg:To>8</v8msg:To>
       <v8msg:From>1</v8msg:From>
       <v8msg:MessageNo>9666</v8msg:MessageNo>
       <v8msg:ReceivedNo>11314</v8msg:ReceivedNo>
   </v8msg:Header>
</v8msg:Message>

Здесь Message это имя документа а http://v8.1c.ru/messages это пространство имен

ДокументDOM удобная компонента для создания xml, в отличие от записьXML позволяет делать это не последовательно

народ, подскажите как перечисление из схемы вытащить?

<xs:simpleType name="EnumRef.ПолФизическогоЛица">
       <xs:restriction base="xs:string">
           <xs:enumeration value=""/>
           <xs:enumeration value="Мужской"/>
           <xs:enumeration value="Женский"/>
       </xs:restriction>
</xs:simpleType>

ОбъектФизЛицо.DeletionMark        = ФизЛицоОбъект.ПометкаУдаления;
ОбъектФизЛицо.Description        = ФизЛицоОбъект.Наименование;
ОбъектФизЛицо.IsFolder            = ФизЛицоОбъект.ЭтоГруппа;
ОбъектФизЛицо.Parent            = ФизЛицоОбъект.Родитель;
ОбъектФизЛицо.Ref            = ФизЛицоОбъект.Ссылка.УникальныйИдентификатор();
ОбъектФизЛицо.ДатаРождения        = ФизЛицоОбъект.Ссылка.ДатаРождения;
ОбъектФизЛицо.ИНН            = ФизЛицоОбъект.ИНН;
ОбъектФизЛицо.КодИМНС            = ФизЛицоОбъект.КодИМНС;
ОбъектФизЛицо.Пол            = ???

то есть тут перечисление нужно указать из схемы. Как?

В схеме задано что базовый тип строка. Она просто ограничена определенными значениями. Значит так:
ОбъектФизЛицо.Пол = "Мужской";

(20)Ооо, сэнкс

Получил xml:

<?xml version="1.0" encoding="UTF-8"?>
<Данные>
   <CatalogObject.ФизическиеЛица xmlns="http://v8.1c.ru/8.1/data/enterprise/current-config" xmlns:xsd="http://www.w3.org/2001/XMLSchema"

xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
       <IsFolder>false</IsFolder>
       <Ref>39c0ea50-237b-11df-8584-0007e92fb5cd</Ref>
       <DeletionMark>false</DeletionMark>
       <Parent>dfeb07c2-a71c-11de-997f-0007e92fb5cd</Parent>
       <Description>Иванов Леонид Анатольевич</Description>
       <ДатаРождения>1985-02-02T00:00:00</ДатаРождения>
       <Пол>Мужской</Пол>
       <ИНН/>
       <КодИМНС/>
       <Сотрудник>true</Сотрудник>
   </CatalogObject.ФизическиеЛица>
</Данные>

Не читается гад

по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: {http://v8.1c.ru/8.1/data/enterprise/current-config}CatalogObject.ФизическиеЛица    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType
по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: {http://v8.1c.ru/8.1/data/enterprise/current-config}IsFolder    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType

и все таки, что то не так делаю.
Конфигурация-Источник(КИ)
Конфигурация-Приемник(КП)

Из КП выгрузил схему "C:\UPR.xsd"
В КИ делаю:

   
ЗаписьXML = Новый ЗаписьXML;
ИмяФайла ="c:\XML_выгрузка.xml";
ЗаписьXML.ОткрытьФайл(ИмяФайла);
ЗаписьXML.ЗаписатьОбъявлениеXML();
Пути = Новый Массив();
Пути.Добавить("C:\UPR.xsd");
Фабрика = СоздатьФабрикуXDTO(Пути);
НовыйСериализаторXDTO = Новый СериализаторXDTO(Фабрика);

ТипФизЛицо = Фабрика.Тип("http://v8.1c.ru/8.1/data/enterprise/current-config", "CatalogObject.ФизическиеЛица");
ОбъектФизЛицо = Фабрика.Создать(ТипФизЛицо);

Зс  = Новый Запрос;
зс.Текст = "ВЫБРАТЬ ПЕРВЫЕ 1
|    ФизическиеЛица.Ссылка КАК ФизЛицо
|ИЗ
|    Справочник.ФизическиеЛица КАК ФизическиеЛица " ;

выборка = зс.Выполнить().Выбрать();

ЗаписьXML.ЗаписатьНачалоЭлемента("Данные");

Пока выборка.Следующий() Цикл

ФизЛицоОбъект = выборка.ФизЛицо.ПолучитьОбъект();

ОбъектФизЛицо.DeletionMark = ФизЛицоОбъект.ПометкаУдаления;
ОбъектФизЛицо.Description = ФизЛицоОбъект.Наименование;
ОбъектФизЛицо.IsFolder = ФизЛицоОбъект.ЭтоГруппа;
ОбъектФизЛицо.Parent = ФизЛицоОбъект.Ссылка.Родитель.УникальныйИдентификатор();
ОбъектФизЛицо.Ref = ФизЛицоОбъект.Ссылка.УникальныйИдентификатор();

Если НЕ ФизЛицоОбъект.ЭтоГруппа Тогда
   ОбъектФизЛицо.ДатаРождения = ФизЛицоОбъект.ДатаРождения;
   ОбъектФизЛицо.ИНН = ФизЛицоОбъект.ИНН;
   ОбъектФизЛицо.КодИМНС = ФизЛицоОбъект.КодИМНС;
   Если ФизЛицоОбъект.Пол = Перечисления.ПолФизическихЛиц.Мужской Тогда
       ОбъектФизЛицо.Пол = "Мужской"
   ИначеЕсли  ФизЛицоОбъект.Пол = Перечисления.ПолФизическихЛиц.Женский Тогда
       ОбъектФизЛицо.Пол = "Женский"
   Иначе
       ОбъектФизЛицо.Пол = ""
   КонецЕсли;
   ОбъектФизЛицо.Сотрудник = Истина;
КонецЕсли;
Фабрика.ЗаписатьXML(ЗаписьXML, ОбъектФизЛицо);

КонецЦикла;
ЗаписьXML.ЗаписатьКонецЭлемента();
ЗаписьXML.Закрыть();

В КП Делаю:


ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.ОткрытьФайл(ИмяФайла);
ФЛОбъект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
ФЛОбъект.ОбменДанными.Загрузка = Истина;
ФЛОбъект.Записать();
ЧтениеXML.Закрыть();

Выходной файл:
<Данные>
<CatalogObject.ФизическиеЛица>
<IsFolder>true</IsFolder>
<Ref>91a2ce24-7de9-11da-9e32-577754503030</Ref>
<DeletionMark>false</DeletionMark>
<Parent>00000000-0000-0000-0000-000000000000</Parent>
<Description>ООО Рога и Копыта</Description>
</CatalogObject.ФизическиеЛица>
</Данные>

на строке
ФЛОбъект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
в КП валится по ошибке

где че упустил?) сериализатор наверно при выгрузке?

тонет черт

юп

ох ты какой шустрый :)
а как он должен преобразовать в ФизЛицо элемент Данные? у него в схемах пространстве имен "http://v8.1c.ru/8.1/data/enterprise/current-config" для элемента "CatalogObject.ФизическиеЛица" нет никакого элемента с названием "Данные" :)

ааа)

дак блин) надо же при записи корневой элемент указать, а то ругается) щас попробуем разпарсить Данные сначала, и обходить элементы на втором уровне

кроме того из твоего файла и кода он даже не знает что ты вообще физ.лицо хочешь получить

дак да

{Форма.Форма.Форма(7)}: Ошибка при вызове метода контекста (ПрочитатьXML)
ФЛОбъект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: CatalogObject.ФизическиеЛица    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType
по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: IsFolder    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType

вот именно anyType

как быть?

короче..
во-первых: надо в xml файле указать пространство имен (ну или придется в ПрочитатьXML тип указывать).
во-вторых: надо сначала зайти в элемент Данные, а потом уже читать объект ФЛ.
ну и наверно в-третьих: элемент должен соответствовать схеме, подозреваю что он у тебя не полный.

ну я его не заполняю ибо у каталогов(групп) нет реквизитов а null не запишешь

(38) Если схема статична, почему бы её не импортировать?

(39) а ну это правильно, именно так и надо.

>>во-первых: надо в xml файле указать пространство имен
в котором месте?

в элементе Данные например, или можно в каждом элементе CatalogObject.ФизическиеЛица указывать

в данных не сканало, а вот в
<?xml version="1.0" encoding="UTF-8"?>

   <CatalogObject.ФизическиеЛица xmlns="http://v8.1c.ru/8.1/data/enterprise/current-config"

xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
       <IsFolder>true</IsFolder>
       <Ref>91a2ce04-7de9-11da-9e32-777054503030</Ref>
       <DeletionMark>false</DeletionMark>
       <Parent>00000000-0000-0000-0000-000000000000</Parent>
       <Description>Рога и копыта</Description>
   </CatalogObject.ФизическиеЛица>

нусёё... [потирая руки]. Щас напишем кучу кода)))
спс, мозг DmitrO

вот так тоже должно получиться:
ЗаписьXML.ЗаписатьНачалоЭлемента("Данные");
ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("", "http://v8.1c.ru/8.1/data/enterprise/current-config");
ЗаписьXML.ЗаписатьСоответствиеПространстваИмен("xsi", "http://www.w3.org/2001/XMLSchema-instance");

разница только в том, что текста меньше будет (в каждом элементе CatalogObject.ФизическиеЛица не надо будет указывать пространства имен)

да да, так и сделал)

всем прив =) опять я)
какой-то косяк при чтении
Структура xml:

<?xml version="1.0" encoding="UTF-8"?>
<Данные xmlns="http://v8.1c.ru/8.1/data/enterprise/current-config" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
   <CatalogObject.ФизическиеЛица>
       <IsFolder>true</IsFolder>
       <Ref>91a2ce04-7de9-11da-9e32-777054503030</Ref>
       <DeletionMark>false</DeletionMark>
       <Parent>00000000-0000-0000-0000-000000000000</Parent>
       <Description>МОЯ ООО</Description>
   </CatalogObject.ФизическиеЛица>
</Данные>

Читаю:

ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.ОткрытьФайл(ИмяФайла);

Пока ЧтениеXML.Прочитать() Цикл
   // Обработка узла XML
   Если ЧтениеXML.Имя = "Данные" И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
       Пока ЧтениеXML.Прочитать() Цикл
           
           ФЛОбъект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
           ФЛОбъект.ОбменДанными.Загрузка = Истина;
           ФЛОбъект.Записать();
                       
       КонецЦикла;
   КонецЕсли;
КонецЦикла;

ЧтениеXML.Закрыть();


смотрел в отладке, URI проставляется от родителя, однако при попытке прочитать элемент:
ФЛОбъект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
валится фэйл

юп

.

не тони

ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.ОткрытьФайл(ИмяФайла);
ЧтениеXML.ПерейтиКСодержимому(); //Переходим на узел: начало элемента Данные
ЧтениеXML.Прочитать(); //Читаем следующий узел: за узлом Данные идет первый CatalogObject.ФизическиеЛица
Пока ЧтениеXML.ТипУзла<>ТипУзлаXML.КонецЭлемента Цикл //будем читать сериализатором пока не встретим конец узла Данные
   Объект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
   Объект.ОбменДанными.Загрузка = Истина;
   Объект.Записать();
КонецЦикла;
ЧтениеXML.Закрыть();

(52) тож самое

Также доходит до элемента CatalogObject.ФизическиеЛица

Пространство тоже - http://v8.1c.ru/8.1/data/enterprise/current-config

и тоже при попытки прочитать Сериализатором валит фэйл:

{Форма.Форма.Форма(32)}: Ошибка при вызове метода контекста (ПрочитатьXML)
   Объект = СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: {http://v8.1c.ru/8.1/data/enterprise/current-config}CatalogObject.ФизическиеЛица    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType
по причине:
Ошибка преобразования данных XDTO:
НачалоСвойства: {http://v8.1c.ru/8.1/data/enterprise/current-config}IsFolder    Форма: Элемент    Тип: {http://www.w3.org/2001/XMLSchema}anyType

мне в получателе же не надо никаких пакетов описывать, если я из источника выгружал по схеме Конфы-приемника?

чото с пространством

Нет, с пространством все нормально.
Тогда у тебя, скорее всего, просто содержимое CatalogObject.ФизическиеЛица не соответствует схеме, какраз то что я и говорил в-третьих в (38).

ааа, в твоем коде он до isfolder опускается )

Код у справочника есть (в метаданных)? Если есть, то где элемент Code в файле?

нет ни кода, ни владельца

ошибка происходит на элементе приведенном в (48)?

еще по примеру в (48):
В метаданных у справочника стоит что он иерархический (наличие элемента Parent)?
В метаданных у справочника больше нет реквизитов определенных для группы?
В метаданных у справочника нет предопределенных элементов?

дак я ж по схеме фабрику при выгрузке делал, а она ругается, када ей гамно подсовываешь, все поля заполнял из фабрики

принадлежность реквизитов к группе проверь

кароче в получателе перестала загружаться(((
CatalogObject.ФизическиеЛица  - энитайп и всё

При выгрузке из источника, все реквизиты справочника заполняешь ?

да, сейчас все, результат - тот  же

самое страшное, что вчера загружалось с только заполненными
<IsFolder>
<Ref>
<DeletionMark>
<Parent>
<Description>
и я ничего не менял вродь)

я правильно делаю со схемой? В источнике при создании фабрики использую выгруженную из получателя http://v8.1c.ru/8.1/data/enterprise/current-config
В Получателе только делаю прочитать СериализаторXDTO.ПрочитатьXML()?
в получателе это же пространство имен?
http://v8.1c.ru/8.1/data/enterprise/current-config

связанных ссылки оставляю пустыми (Parent), для теста

етишь его маму))))
работает! в! ТОЛСТОМ клиенте!!!

всем привет) новый вопрос)
Как в xdto заполнить пустой ссылкой?
Например, есть некий справочник

       <xs:complexType name="CatalogObject.ПапкиФайлов">
       <xs:sequence>
           <xs:element name="Ref" type="tns:CatalogRef.ПапкиФайлов"/>
           <xs:element name="DeletionMark" type="xs:boolean"/>
           <xs:element name="Parent" type="tns:CatalogRef.ПапкиФайлов"/>
           <xs:element name="Code" type="xs:string"/>
           <xs:element name="Description" type="xs:string"/>
           <xs:element name="Описание" type="xs:string"/>
           <xs:element name="Ответственный" type="tns:CatalogRef.Пользователи"/>
           <xs:element name="ДатаСоздания" type="xs:dateTime"/>
           <xs:element name="ДополнительныеРеквизиты" type="tns:CatalogTabularSectionRow.ПапкиФайлов.ДополнительныеРеквизиты" minOccurs="0" maxOccurs="99999"/>
       </xs:sequence>
   </xs:complexType>

при заполнении фабрики мне нужно в элемент Ответственный заполнить пустую ссылку справочника Пользователи

   <xs:complexType name="CatalogObject.Пользователи">
       <xs:sequence>
           <xs:element name="Ref" type="tns:CatalogRef.Пользователи"/>
           <xs:element name="DeletionMark" type="xs:boolean"/>
           <xs:element name="Description" type="xs:string"/>
           <xs:element name="ИдентификаторПользователяИБ" type="v8:UUID"/>
           <xs:element name="ФизическоеЛицо" type="tns:CatalogRef.ФизическиеЛица"/>
           <xs:element name="ТекущееПодразделение" type="tns:CatalogRef.ЦФО"/>
           <xs:element name="КонтактнаяИнформация" type="tns:CatalogTabularSectionRow.Пользователи.КонтактнаяИнформация" minOccurs="0" maxOccurs="99999"/>
       </xs:sequence>

00000000-0000-0000-0000-000000000000?

Короче так:
1). В схеме, у всех реквизитов (кроме стандартных, которые должны быть заполнены обязательно и кроме подчиненных ТЧ) проставь свойство Возможно пустое = Истина (в схеме это выглядит как nillable="true").
2). Заполняешь все стандартные реквизиты (code, description и т.д...), заполняешь нужные тебе реквизиты, вызываешь ИнициализироватьПоУмолчанию(ОбъектXDTO)

Процедура ИнициализироватьПоУмолчанию(ОбъектXDTO)
   // Все реквизиты которые забиваются Неопределенно в схеме должны иметь nillable="true"
   ТипСписокXDTO = Тип("СписокXDTO");
   Для каждого СвойствоОбъектаXDTO Из ОбъектXDTO.Свойства() Цикл
       Если НЕ ТипЗнч(ОбъектXDTO[СвойствоОбъектаXDTO.Имя]) = ТипСписокXDTO Тогда
           Если НЕ ОбъектXDTO.Установлено(СвойствоОбъектаXDTO) Тогда
               ОбъектXDTO[СвойствоОбъектаXDTO.Имя] = Неопределено;                
           КонецЕсли;
       КонецЕсли;
   КонецЦикла;
КонецПроцедуры

спс

Продолжаем =)
(73)чем атрибут nillable="true" отличается от minOccurs="0"?

Делаю ОбъектДоговор.Owner = Договор.Владелец.Ссылка.УникальныйИдентификатор();
У Owner  тип {http://v8.1c.ru/8.1/data/enterprise}AnyRef
Ругается:
Ошибка отображения типов:
Отображение типа 'УникальныйИдентификатор' в тип '{http://www.w3.org/2001/XMLSchema}string'
AnyRef разве не ограничен строкой?

все,к строке преобразовал уид, зафурычило