Для Каждого Запись из ТЗ Цикл
        Движение = РегистрыНакопления.ДвижениеКарты.СоздатьНаборЗаписей();
        Движение.Отбор.Регистратор.Установить(Запись.Регистратор);
        ЗаписьРегистра = Движение.ДобавитьПриход();
        ЗаписьРегистра.Активность = Истина;
        ЗаписьРегистра.КодДок = Запись.КодДок;
        ЗаписьРегистра.Количество =Запись.Количество;
        ЗаписьРегистра.Номенклатура = Запись.Номенклатура;
        ЗаписьРегистра.НоменклатурнаяГруппа = Запись.НоменклатурнаяГруппа;
        ЗаписьРегистра.Организация = Запись.Организация;
        ЗаписьРегистра.Период = Запись.Период;
        ЗаписьРегистра.ПодразделениеОрганизации = Запись.ПодразделениеОрганизации;
        ЗаписьРегистра.Склад = Запись.Склад;
        Движение.Записать();
    КонецЦикла;

В Итоге в регистре только одна запись из 3-х, как сделать так чтобы были все записи?

набор записей и отбор сделать ДО цикла

(1)+ а запись после

Регистратор из ТЗ идет

(0) почитай про команду Записать(), у тебя при записи всё что в отборе удаляется
PS. прочитай про команду ЗаполнитьЗначенияСвойств()

(3) тогда делай Прочитать() перед добавлением записи

(5) примерную конструкцию можешь набрасать?

Движение.Записать(Ложь);

вообще проще так
Для Каждого Запись из ТЗ Цикл
        Движение = РегистрыНакопления.ДвижениеКарты.СоздатьНаборЗаписей();
        Движение.Отбор.Регистратор.Установить(Запись.Регистратор);
        ЗаписьРегистра = Движение.ДобавитьПриход();
        ЗаписьРегистра.Активность = Истина;
        ЗаполнитьЗначенияСвойств(ЗаписьРегистра,Запись);
        Движение.Записать(Ложь);
    КонецЦикла;

темпТЗ = ТЗ.Скопировать();
темпТЗ.Свернуть("Регистратор");
Для каждого строкаРегистратор Из темпТЗ Цикл
     СтрокиСЭтимРегистратором = ТЗ.НайтиСтроки(Новый Структура("Регистратор",строкаРегистратор.Регистратор));
     Движение = РегистрыНакопления.ДвижениеКарты.СоздатьНаборЗаписей();
     Движение.Отбор.Регистратор.Установить(Запись.Регистратор);
   Для каждого запись Из СтрокиСЭтимРегистратором Цикл
        ЗаписьРегистра = Движение.ДобавитьПриход();
        ЗаписьРегистра.Активность = Истина;
        ЗаписьРегистра.КодДок = Запись.КодДок;
        ЗаписьРегистра.Количество =Запись.Количество;
        ЗаписьРегистра.Номенклатура = Запись.Номенклатура;
        ЗаписьРегистра.НоменклатурнаяГруппа = Запись.НоменклатурнаяГруппа;
        ЗаписьРегистра.Организация = Запись.Организация;
        ЗаписьРегистра.Период = Запись.Период;
        ЗаписьРегистра.ПодразделениеОрганизации = Запись.ПодразделениеОрганизации;
        ЗаписьРегистра.Склад = Запись.Склад;
   КонецЦикла;
   Движение.Записать();
КонецЦикла;

(9)эээ... там ошибочка в 6 строке, надо
Движение.Отбор.Регистратор.Установить(строкаРегистратор.Регистратор);

тут ещё такой вопрос: у документов до этого есть движения по регистру или нет?

Спасибо (7)

Всем Спасибо

(11) могут быть!

(14) их надо чистить или добавляешь к ним?

надо чистить

(16) тогда вариант (9) правильнее, в моем варианте не чистятся

Круто спасибо)

Скомбинировал:
    темпТЗ = ТЗ.Скопировать();
    темпТЗ.Свернуть("Регистратор");
    Для каждого строкаРегистратор Из темпТЗ Цикл
        СтрокиСЭтимРегистратором = ТЗ.НайтиСтроки(Новый Структура("Регистратор",строкаРегистратор.Регистратор));
        Движение = РегистрыНакопления.ДвижениеКарты.СоздатьНаборЗаписей();
        Движение.Отбор.Регистратор.Установить(строкаРегистратор.Регистратор);
        Для каждого запись Из СтрокиСЭтимРегистратором Цикл
            ЗаписьРегистра = Движение.ДобавитьПриход();
            ЗаписьРегистра.Активность = Истина;
            ЗаполнитьЗначенияСвойств(ЗаписьРегистра,Запись);
        КонецЦикла;
        Движение.Записать();
    КонецЦикла;