Приветствую всех.
Подскажите можно стандартными средствами, без использования макетов оформления, закрепить шапку таблицы отчета?
Заранее спасибо.

после вывода в поле табдока...

Еще раз спасибо, а по умолчанию как нитбудь не сделать? Лазить в Таблица->Вид постоянно приходится.

(2) Видимо код писАть нужно

(3) Понятно. Халявы не будет, а жаль.

Создаю форму отчета и в ней программно фиксирую нужное количество строк и колонок

(5) А я лезу в настройки отчета и задаю 80 (утрирую) группировок. Не угадаешь какой высоты шапка будет.

(6) все можно угадать программно...

v8: Разбираюсь с компоновкой данных...

Самое простое что я смог придумать.
Фиксирует шапку при любых отборах.

Процедура скдФиксироватьШапкуОтчета(ТабДок, Фиксировать, Строка = "Номенклатура", Поправка = 0) Экспорт
   
   Если Фиксировать Тогда
       
       Область = ТабДок.НайтиТекст(Строка,,,,Истина);
       ТабДок.ФиксацияСверху = ?(ЗначениеЗаполнено(Область), Область.Верх + Поправка, 0);    
       
   Иначе
       
       ТабДок.ФиксацияСверху = 0;
       
   КонецЕсли;
   
КонецПроцедуры

(9) бест! зачет, а если большой отчет?

(10) не вижу разницы. Работает впринципе везде корректно. Клавное колонку для поиска правильно указать.

(11) по скорости

(12) У мну не было таких отчотов ещё, чтобы хоть как-то заметно задумывалось.

(9) А если Номенклатуру убрали из группировок?

(14) тогда увы и ах! Будут, умники, жить без шапки.

я сделал так:  http://i066.radikal.ru/1004/6c/1c137c2371ee.jpg

+ кнопка "закрепить". Закрепляет шапку по текущую выделенную область. Самое простое, имхо.

А посмотреть, как сделано в типовых?.....

(18) никак там не сделано и не фиксируется

(19) в ЗУПе ВСЕ отчёты на СКД и все фиксируются

(20) например?

я имел ввиду как там сделано, приведи здесь - у меня нет типовой зуп

(21) Хм. Посмотрел сам - вроде и правда не фиксируется. Значит где-то ещё видел
а конструкция такая должна быть:

   ПроцессорВывода.НачатьВывод();

   ТаблицаЗафиксирована = Ложь;
   Пока Истина Цикл
       ЭлементРезультата = ПроцессорКомпоновкиДанных.Следующий();
       Если ЭлементРезультата= Неопределено Тогда
           Прервать;    
       Иначе    
           ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
           Если Не ТаблицаЗафиксирована И ЭлементРезультата.ЗначенияПараметров.Количество() >  0 Тогда
               ТаблицаЗафиксирована = Истина;
               Таб.ФиксацияСверху = Таб.ВысотаТаблицы;
             КонецЕсли;
       КонецЕсли;
   КонецЦикла;
   ПроцессорВывода.ЗакончитьВывод();

(23) спасибо) добавил в базу знаний)

Процедура глВывестиРезультатКомпоновкиСАвтофиксациейСтрок( Таб,
                                                           ПроцессорКомпоновкиДанных,
                                                           ЭлементыРасшировки,
                                                           Знач МассивИгнорируемыхПолей = Неопределено,
                                                           РазрешитьПрерывание = Истина) Экспорт

ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ПроцессорВывода.УстановитьДокумент(Таб);
ПроцессорВывода.НачатьВывод();
ФиксацияВыполнена = Ложь;
Если МассивИгнорируемыхПолей = Неопределено Тогда
    МассивИгнорируемыхПолей = Новый Массив;
КонецЕсли;
Пока Истина Цикл
    ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();
    Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда
        Прервать;
    КонецЕсли;
   
    // Автофиксация
    Если Не ФиксацияВыполнена Тогда
        Для Каждого ЗначениеПараметра Из ЭлементРезультатаКомпоновкиДанных.ЗначенияПараметров Цикл
            Если ТипЗнч(ЗначениеПараметра.Значение) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда
                ЗначенияПолейРасшифровки = ЭлементыРасшировки[ЗначениеПараметра.Значение].ПолучитьПоля();
                Для Каждого ЗначениеПоляРасшифровки Из ЗначенияПолейРасшифровки Цикл
                    Если МассивИгнорируемыхПолей.Найти(ЗначениеПоляРасшифровки.Поле) = Неопределено Тогда
                        Таб.ФиксацияСверху = Таб.ВысотаТаблицы;
                        ФиксацияВыполнена = Истина;
                        Прервать;
                    КонецЕсли;
                КонецЦикла;
                Если ФиксацияВыполнена Тогда
                    Прервать;
                КонецЕсли;
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;
   
    ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);
    Если РазрешитьПрерывание Тогда
        #Если Клиент тогда
        ОбработкаПрерыванияПользователя();
        #КонецЕсли
    КонецЕсли;
КонецЦикла;
ПроцессорВывода.ЗакончитьВывод();

КонецПроцедуры

(2) вынеси кнопку "Зафиксировать шапку" на панель
(23)    Таб.ФиксацияСверху = Таб.ВысотаТаблицы - 1;