Всем привет!

Научился создать очередь:
qinfo  = Новый COMОбъект("MSMQ.MSMQQueueInfo");
   qinfo.PathName = ".\private$\Test";
   qinfo.Create();

а дальше не могу понять как отправить сообщение в очередь и как прочитать. Пробую:
       qinfos  = Новый COMОбъект("MSMQ.MSMQQueueInfos");
       query = Новый COMОбъект("MSMQ.MSMQQuery");
   qinfos = query.LookupQueue("Test");
   qinfo = qinfos.Next;

       Если qinfo = null Тогда
       Сообщить("Очередь не найдена")
   КонецЕсли;

на строке: qinfos = query.LookupQueue("Test");    вылезает ошибка:

Ошибка при вызове метода контекста (LookupQueue): Произошла исключительная ситуация (MSMQQuery): Недопустимая строка с указанием класса

Помогите кто может простеньким примерчиком. Спасибо.

http://www.emanual.ru/download/www.eManual.ru_4364.html

да по этой статье и учусь, но непонятно

Dim query As New MSMQQuery
Dim qinfos As MSMQQueueInfos
Set qinfos = query.LookupQueue(Label:="Test")


Label это вроде метка очереди но как последнюю строку переписать на 1С?

На ИТС есть пример работы с MSMQ и ВебСферой в контексте отправки и приема сообщений распределенки ...

(0) "Проф. разработку" читал?...

спасибо SilentMan нашел пример

(4) а  что такое "Проф.разработка"?

(6) Книжка такая толстая по восьмерке, там на эту тему есть, если не ошибаюсь...

спасибо попробую найти, посмотреть

лови сырцы из проф. разработки

   Процедура КнопкаВыполнитьНажатие(Кнопка)
   
       // Флаги
       MQ_SEND_ACCESS = 2;
       MQ_DENY_NONE = 0;
   
       qinfo = Новый COMОбъект("MSMQ.MSMQQueueInfo");
       
       ОчередьОбменаMSMQ = ".\MyLocale";
       ИмяФайлаСообщения = "data.xml";
       
       // Формируем путь к очереди на удаленном компьютере
       qinfo.PathName = ОчередьОбменаMSMQ + "_" + "ЦентрОфис";
       
       // Если очередь не создана, создаем
       Попытка
           qinfo.Create();
       Исключение
       КонецПопытки;
       
       // Открываем очередь на запись
       Очередь = qinfo.Open(MQ_SEND_ACCESS, MQ_DENY_NONE);
       
       ДанныеОбмена = Новый ЧтениеТекста;
       ДанныеОбмена.Открыть("c:\out.xml");
       
       // Создаем сообщение, содержащее данные обмена
       Сообщение = Новый COMОбъект("MSMQ.MSMQMessage");
       Сообщение.Label = ИмяФайлаСообщения;
       Сообщение.Body = ДанныеОбмена.Прочитать();
       Сообщение.ResponseQueueInfo = qinfo;
       
       // Помещаем сообщение в очередь
       Сообщение.Send(Очередь);
       
       Сообщить(" - Помещен файл " + ИмяФайлаСообщения + " в очередь " + ОчередьОбменаMSMQ);
       
       Очередь.Close();
       ДанныеОбмена.Закрыть();
   
   КонецПроцедуры

ещё

   
Процедура Загрузить(Кнопка)

   // Флаги
   MQ_DENY_NONE = 0;
   MQ_RECEIVE_ACCESS = 1;
   MQ_NO_TRANSACTION = 0;

   ОчередьОбменаMSMQ = ".\MyLocale";
   
   qinfo = Новый COMОбъект("MSMQ.MSMQQueueInfo");
   
   // Находим позицию начала имени очереди в АдресОбменаMSMQ
   // Хотя в нашем случае могли установить Индекс=2
   Индекс = СтрДлина(ОчередьОбменаMSMQ);
   Пока (Индекс <> 0) Цикл
       
       Если Сред(ОчередьОбменаMSMQ, Индекс, 1) = "\" Тогда
           Прервать;
       КонецЕсли;
       
       Индекс = Индекс - 1;
       
   КонецЦикла;
   
   // Собираем путь к очереди для чтения данных обмена
   // В нашем случае qinfo.PathName = ".\MyLocale_ЦентрОфис"
   qinfo.PathName = ".\" + Прав(ОчередьОбменаMSMQ, СтрДлина(ОчередьОбменаMSMQ) - Индекс) + "_" + "ЦентрОфис";
                   
   Попытка
       qinfo.Create();
   Исключение
   КонецПопытки;
   
   // Открываем очередь
   Очередь = qinfo.Open(MQ_RECEIVE_ACCESS, MQ_DENY_NONE);
   
   // Временный объект необходим для поиска последнего сообщения
   СообщениеВрем = Новый COMОбъект("MSMQ.MSMQMessage");

   // Читаем первое сообщение
   СообщениеВрем = Очередь.Receive(MQ_NO_TRANSACTION, , , 0);
   
   Пока (СообщениеВрем <> Неопределено) Цикл
       
       Сообщение = СообщениеВрем;

       // Читаем последующие сообщения, если они присутствуют
       СообщениеВрем = Очередь.Receive(MQ_NO_TRANSACTION, , , 0);
       
   КонецЦикла;
   
   // Закрываем очередь
   Очередь.Close();
   
   // Если получили сообщение, разбираем его и передаем данные обмена
   // дальше для обработки
   Если Сообщение <> Неопределено Тогда
       ИмяФайлаСообщения = Сообщение.Label;
       ФайлОбмена = Новый ЗаписьТекста("c:\input.xml");
       ФайлОбмена.Записать(Сообщение.Body);
       ФайлОбмена.Закрыть();
       Сообщить(" - Принят файл обмена данными " + ИмяФайлаСообщения + " из очереди " + ОчередьОбменаMSMQ);
   КонецЕсли;
   
КонецПроцедуры

больше там ничего нет, есть WSMQ

Спасибо всем, разобрался