Помогите нужна ertшка(рабочая, провереная) для апарата Samsung RF4615 апарат фискализирован

Гнусмас не работает с ертешками

И с, чем же он работает?

с лентами кассовыми...

тебе для начала драйвер надо. Или из командной строки хотишь рОбить? Есть и такие варианты.

Ты хоть раз кассы подключала?

Дрова есть.

фискализирован

(5)И чо?
Вот те образец для Мини-600... дальше иппайся сам
Перем НазваниеДрайвера;

//===========================================            
Процедура ИнициализацияДрайвера()                      
   
КонецПроцедуры                

//===========================================            
Процедура Инициализация()            
   
   ЭККА = глРасшифровка.Получить("Касса");
       
   Состояние("Инициализация драйвера ЭККА "+ЭККА);
   
   спПараметры = СоздатьОбъект("СписокЗначений");
   глПарсить(ЭККА.ПараметрыИнициализации,спПараметры,РазделительСтрок);

   Попытка
       Драйвер = CreateObject("MiniECR_OLE.FiscPrn");
       глПереченьДрайверов.ДобавитьЗначение(Драйвер,НазваниеДрайвера+ЭККА.Код);
       глТрассировка("Подключен драйвер для ЭККА "+ЭККА,2);
   Исключение
       глТрассировка("Ошибка ЭККА :"+ОписаниеОшибки(),0);
       глТрассировка("Возможно, драйвер не установлен !",2);
   КонецПопытки;
   
   
КонецПроцедуры

//===========================================            
Процедура ПечатьЧека()
   
   Док = глРасшифровка.Получить("Документ"); // Чек
   
   Если ПустоеЗначение(Док)=1 Тогда
       Возврат;
   КонецЕсли;
   
   Драйвер = глПереченьДрайверов.Получить(НазваниеДрайвера+Док.ЭККА.Код);
   
   Если ПустоеЗначение(Драйвер)=1 Тогда
       глТрассировка("Не найден драйвер ЭККА",1);
       Возврат;
   КонецЕсли;
   
   спПараметры = СоздатьОбъект("СписокЗначений");
   глПарсить(Док.ЭККА.ПараметрыИнициализации,спПараметры,РазделительСтрок);

   Порт = Число(спПараметры.Получить("Порт"));
   Если ПустоеЗначение(Порт)=1 Тогда
       Порт = 1;
   КонецЕсли;
   
   Скорость = Число(спПараметры.Получить("Скорость"));
   Если ПустоеЗначение(Скорость)=1 Тогда
       Скорость = 19200;
   КонецЕсли;
   ЕдиницаВНаименовании = Число(спПараметры.Получить("ЕдиницаВНаименовании"));
   Если ЕдиницаВНаименовании = 1 Тогда
       ДлинаНаименования = Число(спПараметры.Получить("ДлинаНаименования"));
       Если ПустоеЗначение(ДлинаНаименования) = 1 Тогда
           ДлинаНаименования = 11;
       КонецЕсли;
   КонецЕсли;
   
   Попытка
       РезЧек = 1;
       
       Док.ВыбратьСтроки();
       Пока Док.ПолучитьСтроку()=1 Цикл
           // печать строки
           // поскольку ставку НДС можно задать только для отдела,
           // то предполагаем, что товары разделены по отделам в соответсвии со ставками НДС
           НалоговаяГр = глНалоговаяГруппа(Док.Товар.СтавкаНДС.Получить(Док.ДатаДок));
           Наименование = СокрЛП(Док.Товар.Наименование);
           
           Если ЕдиницаВНаименовании = 1 Тогда
               Единица = " ("+СокрЛП(Док.Единица)+")";
               Наименование = Лев(Наименование,ДлинаНаименования - СтрДлина(Единица))+Единица;
           КонецЕсли;
           
           Рез = Драйвер._SALE(Порт,Скорость,Наименование,Док.Количество,Окр(Док.ЦенаСНДС,2),НалоговаяГр);
           Если Рез = 0 Тогда
               глТрассировка(Шаблон("Ошибка печати строки чека по строке [Док.НомерСтроки] документа !"),0);
               РезЧек = 0;
           КонецЕсли;
       КонецЦикла;
       
       Если РезЧек = 0 Тогда
           // аннулируем чек, если была ошибка
           Драйвер._ANNUL(Порт,Скорость);
           Возврат;
       КонецЕсли;
       
       Рез = 1;
       Если Док.СуммаСкидки > 0 Тогда
           // Скидка на итог
           Рез = Драйвер._SDIS_TOTAL(Порт,Скорость,Док.СуммаСкидки);
       ИначеЕсли Док.СуммаСкидки < 0 Тогда
           // Наценка на итог
           Рез = Драйвер._SEXTRA_TOTAL(Порт,Скорость,-Док.СуммаСкидки);
       КонецЕсли;
       Если Рез=0 Тогда
           глТрассировка("Ошибка при указании скидки/наценки !",0);
           Драйвер._ANNUL(Порт,Скорость);
           Возврат;
       КонецЕсли;
       
       // Полностью оплачен (0 - наличными)
       Рез = Драйвер._PAY(Порт,Скорость,0);
       Если Рез=0 Тогда
           глТрассировка("Ошибка при оплате чека !",0);
       КонецЕсли;
       
       Если Рез =0 Тогда
           // аннулируем чек
           Драйвер._ANNUL(Порт,Скорость);
       Иначе
           Док.ЧекПробит=1;
       КонецЕсли;
       
       Драйвер._ClosePort();
   Исключение
       глТрассировка("Ошибка ЭККА :"+ОписаниеОшибки());
       Док.ЧекПробит=0;
   КонецПопытки;

КонецПроцедуры                  

//===========================================            
Процедура Отчет()
   
   Сообщить("Драйвер фискального принтера не поддержвает загрузку отчета!");
   
КонецПроцедуры                  

//===========================================            
Процедура ВыгрузитьАртикулы()
   
   Сообщить("Драйвер фискального принтера не поддержвает выгрузку артикулов!");
   
КонецПроцедуры


//===========================================            
Процедура ПриОткрытии()
   Параметр = глРасшифровка.Получить("Парам");
   Если Параметр = "Инициализация" тогда
       Инициализация();
   ИначеЕсли Параметр = "ПодключитьДрайвер" тогда
       ИнициализацияДрайвера();
   ИначеЕсли Параметр = "ВыгрузитьАртикулы" тогда
       ВыгрузитьАртикулы();
   ИначеЕсли Параметр = "ПечатьЧека" тогда
       ПечатьЧека();
   ИначеЕсли Параметр = "Отчет" тогда
       Отчет();
   КонецЕсли;
   СтатусВозврата(0);
КонецПроцедуры

НазваниеДрайвера = "МиниФП";

muchs gracias!!!

Вот для "Славича"
Перем НазваниеДрайвера;

// конфигурация пульта
Перем Конф, спСхем, спДаНет, Кассы;

Процедура ПриВыбореЗакладки(Ном,Значение)
   Форма.ИспользоватьСлой("Основной, "+Значение,2);
КонецПроцедуры

// ===============================
Процедура Обновить()
   текСтр = тбКонф.ТекущаяСтрока();
   
   тбКонф.УдалитьСтроки();
   ИмяУстр = "";
   КвоКасс = 0;
   // прочитаем информацию в таблицу
   Конф.MoveFirst();
   Пока Конф.EOF = 0 Цикл
       ИмяУстр = Конф.DeviceName;
       КвоКасс = Конф.Count;
       
       тбКонф.НоваяСтрока();
       тбКонф.НомКассы = Конф.CashNo;
       тбКонф.НомСхемы = Конф.SchemaNo;
       
       Номер = спСхем.НайтиЗначение(тбКонф.НомСхемы);
       Если Номер <> 0 Тогда
           Назв = "";
           спСхем.ПолучитьЗначение(Номер,Назв);
           тбКонф.НазвСхемы = Назв;
       КонецЕсли;
       
       тбКонф.КассирОсн = Конф.UserMain;
       тбКонф.ПарольОсн = Конф.PasswordMain;
       тбКонф.КассирПульт = Конф.UserUI;
       тбКонф.ПарольПульт = Конф.PasswordUI;
       Если Конф.Autorun = 0 Тогда // False
           тбКонф.Автопуск = "Нет";
       Иначе
           тбКонф.Автопуск = "Да";
       КонецЕсли;
       
       Если Конф.State = 1 Тогда
           тбКонф.Состояние = "Изм.";
       ИначеЕсли Конф.State = 2 Тогда
           тбКонф.Состояние = "Нов.";
       ИначеЕсли Конф.State = 3 Тогда
           тбКонф.Состояние = "Удал.";
       КонецЕсли;
       
       Конф.MoveNext();
   КонецЦикла;
   Если текСтр<>0 Тогда
       тбКонф.ТекущаяСтрока(текСтр);
   КонецЕсли;
   
КонецПроцедуры //Обновить

// ===============================
Процедура ПрочитатьКонф()
   Попытка
       Конф.Read();
   Исключение
       глТрассировка(ОписаниеОшибки(),0);
   КонецПопытки;
   Обновить();
КонецПроцедуры //ПрочитатьКонф

// ===============================
Процедура ЗаписатьКонф()
   Попытка
       Конф.Write();
       ПрочитатьКонф();
   Исключение
       глТрассировка(ОписаниеОшибки(),0);
   КонецПопытки;
КонецПроцедуры //ЗаписатьКонф

// ===============================
Процедура ИзмИмяУстр()
   Попытка
       Конф.DeviceName = ИмяУстр;
   Исключение
       глТрассировка("Ошибка :"+ОписаниеОшибки(),0);
       ИмяУстр = Конф.DeviceName;
   КонецПопытки;
КонецПроцедуры //

// ===============================
Процедура РедактироватьЯчейку()
   
   Кол = тбКонф.ТекущаяКолонка();
   Если (Кол = "Состояние") или (Кол = "НомКассы") Тогда
       // эти колонки не редактируются
       Возврат;
   КонецЕсли;
   Если (Кол = "НазвСхемы") Тогда
       // редактируем номер схемы
       Кол = "НомСхемы";
   КонецЕсли;
   
   Стр = тбКонф.ТекущаяСтрока();
   Если Стр = 0 Тогда
       Возврат;
   КонецЕсли;
   
   Конф.Find(тбКонф.НомКассы);
   Если Конф.EOF=-1 Тогда
       глТрассировка("Не найдена редактируемая касса  (серийный номер "+тбКонф.НомКассы+")!!!",0);
       Возврат;
   КонецЕсли;
   
   Зн = тбКонф.ПолучитьЗначение(Стр,Кол);
   Дл = 0;
   Заг = 0;
   Тип = "";
   тбКонф.ПолучитьПараметрыКолонки(Кол,Тип,Дл,,Заг);
   
   Если Кол = "НомСхемы" Тогда
       // выберем из списка
       Поз = 0;
       спСхем.ВыбратьЗначение(Зн,"Выберите тип ЭККА:",Поз,,2);
   ИначеЕсли Кол = "Автопуск" Тогда
       // выберем из списка
       Зн = ?(СокрЛП(Зн)="Да",-1,0);
       Поз = 0;
       спДаНет.ВыбратьЗначение(Зн,"Осуществлять ли автозапуск ?",Поз,,2);
   Иначе
       Если Тип = "Строка" Тогда
           Если ВвестиСтроку(Зн,"Введите " + нРег(Заг), Дл) = 0 Тогда
               Возврат;
           КонецЕсли;
       ИначеЕсли Тип = "Число" Тогда
           Если ВвестиЧисло(Зн,"Введите " + нРег(Заг), Дл,0) = 0 Тогда
               Возврат;
           КонецЕсли;
       КонецЕсли;
   КонецЕсли;

   // запишем изменения
   Попытка
       Если Кол = "НомСхемы" Тогда
           Конф.SchemaNo = Зн;
       ИначеЕсли Кол = "КассирОсн" Тогда
           Конф.UserMain = Зн;
       ИначеЕсли Кол = "ПарольОсн" Тогда
           Конф.PasswordMain = Зн;
       ИначеЕсли Кол = "КассирПульт" Тогда
           Конф.UserUI = Зн;
       ИначеЕсли Кол = "ПарольПульт" Тогда
           Конф.PasswordUI = Зн;
       ИначеЕсли Кол = "Автопуск" Тогда
           Конф.Autorun = Зн;
       КонецЕсли;
       Обновить();
   Исключение
       глТрассировка("Ошибка :"+ОписаниеОшибки(),0);
   КонецПопытки;
КонецПроцедуры //РедактЯчейки

// ===============================
Процедура ДобавитьКассуПульт()
   Зн = 0;
   //Если ВвестиЧисло(Зн,"Введите заводской номер кассы", 12,0) = 0 Тогда
   //    Возврат;
   //КонецЕсли;
   спКассы = СоздатьОбъект("СписокЗначений");
   
   Кассы.MoveFirst();
   Пока Кассы.EOF = 0 Цикл
       спКассы.ДобавитьЗначение(Кассы.CashNo);
       Кассы.MoveNext();
   КонецЦикла;
   Поз = 0;
   Если спКассы.ВыбратьЗначение(Зн,"Выберите кассу", Поз,0,0) = 0 Тогда
       Возврат;
   КонецЕсли;
   Конф.CashNo = Зн;
   Обновить();
КонецПроцедуры //ДобавитьКассуПульт

// ===============================
Процедура УдалитьКассуПульт()
   Конф.Find(тбКонф.НомКассы);
   Если Конф.EOF=-1 Тогда
       глТрассировка("Не найдена редактируемая касса  (серийный номер "+тбКонф.НомКассы+")!!!",0);
       Возврат;
   КонецЕсли;
   Конф.Delete();
   Обновить();
КонецПроцедуры //УдалитьКассуПульт

// ===============================
Процедура ОбновитьКассы()
   
   тбКассы.УдалитьСтроки();
   
   // прочитаем информацию в таблицу
   Кассы.MoveFirst();
   Пока Кассы.EOF = 0 Цикл
       
       тбКассы.НоваяСтрока();
       тбКассы.НомКассы = Кассы.CashNo;
       
       Если Кассы.Updated = 1 Тогда
           тбКассы.Состояние = "Обновлены отчеты";
       ИначеЕсли Кассы.Updated = 2 Тогда
           тбКассы.Состояние = "Обновлены товары";
       ИначеЕсли Кассы.Updated = 3 Тогда
           тбКассы.Состояние = "Обновлены отчеты и товары";
       КонецЕсли;
       
       Кассы.MoveNext();
   КонецЦикла;
   
КонецПроцедуры //ОбновитьКассы

// ===============================
Процедура ДобавитьКассу()
   Зн = "";
   Если ВвестиЧисло(Зн,"Введите заводской номер кассы", 12,0) = 0 Тогда
       Возврат;
   КонецЕсли;
   Кассы.CashNo = Зн;
   ОбновитьКассы();
КонецПроцедуры //ДобавитьКассу

// ===============================
Процедура УдалитьКассу()
   
   Кассы.Find(тбКассы.НомКассы);
   Если Кассы.EOF = -1 Тогда
       ОбновитьКассы();
       Возврат;
   КонецЕсли;
   Кассы.Delete();
   ОбновитьКассы();
КонецПроцедуры //УдалитьКассуПульт


// ===============================
Процедура ВызватьТрансфер()
   Попытка        
       Кассы = СоздатьОбъект("Slavich.Cashes");
   Исключение
       глТрассировка("Не удалось создать объект для доступа к ЭККА!",0);
       глТрассировка("Возможно драйвер не установлен!",0);
       Возврат;
   КонецПопытки;
   Кассы.Transfer();
   Обновить();
КонецПроцедуры //ВызватьТрансфер

// ===============================
Процедура ИзмВидимостьНомСхемы()
   тбКонф.ВидимостьКолонки("НомСхемы",фВидимостьНомСхемы);    
КонецПроцедуры //


//===========================================            
Процедура ИнициализацияДрайвера()                      
   
КонецПроцедуры                

//===========================================            
Процедура Инициализация()
   
   // Инициализации нет
   
КонецПроцедуры

//===========================================
Процедура ПечатьЧека()

   глТрассировка("Печать чеков не поддерживается !");

КонецПроцедуры

//===========================================
Процедура Отчет()
   
   Док = глРасшифровка.Получить("Документ"); // Отчет КА
   
   Если ПустоеЗначение(Док)=1 Тогда
       Возврат;
   КонецЕсли;
   
   ЭККА = Док.ЭККА;
   
   Если ПустоеЗначение(ЭККА)=1 Тогда
       глТрассировка("При вызове драйвера ЭККА не указана касса",0);
       Возврат;
   КонецЕсли;
   
   // читаем отчет ЭККА
   Состояние(" Загрузка отчета ЭККА "+ЭККА);
   
   Попытка        
       Кассы = СоздатьОбъект("Slavich.Cashes");
   Исключение
       глТрассировка("Не удалось создать объект для доступа к ЭККА!",0);
       глТрассировка("Возможно драйвер не установлен!",0);
       Возврат;
   КонецПопытки;
   
   спПараметры = СоздатьОбъект("СписокЗначений");
   глПарсить(ЭККА.ПараметрыИнициализации,спПараметры,РазделительСтрок);
   
   СерийныйНомер = Число(спПараметры.Получить("СерийныйНомер"));
   
   Кассы.Find(СерийныйНомер);
   Если Кассы.EOF = -1 Тогда
       глТрассировка("Касса с серийным номером "+ СерийныйНомер+" не найдена!",0);
       Возврат;
   КонецЕсли;
   
   спрТовары = СоздатьОбъект("Справочник.Номенклатура");
   спУдалить = СоздатьОбъект("СписокЗначений"); // список обработанных отчетов
   
   фЕстьОтчет = 0;
   Отчеты = Кассы.Reports;
   Отчеты.MoveFirst();
   Пока Отчеты.EOF = 0 Цикл
       Отчет = Отчеты.PLURep;
       глТрассировка("Обрабатывается отчет № "+Отчеты.Zno,2);
       // Прйдем по строчкам отчета
       фОшибка = 0;
       Отчет.MoveFirst();
       Пока Отчет.EOF = 0 Цикл
           Код = Отчет.Code;
           Количество = Отчет.Amount;
           Сумма = Отчет.Sum;
           
           // найдем товар
           Если спрТовары.НайтиПоКоду(Код)=1 Тогда
               Док.НоваяСтрока();
               Док.Товар = спрТовары.ТекущийЭлемент();
               Док.Единица = спрТовары.ЕдиницаПоУмолчанию;
               Док.Коэффициент = спрТовары.ЕдиницаПоУмолчанию.Коэффициент;
               Док.Количество = Количество;
               Док.СуммаСНДС = Сумма;
           Иначе
               глТрассировка("Не найден товар с кодом "+Код,0);
               фОшибка = 1;
           КонецЕсли;
           Отчет.MoveNext();
           фЕстьОтчет = 1;
       КонецЦикла;
       Если фОшибка = 0 Тогда
           // если не было ошибок - удалим отчет
           спУдалить.ДобавитьЗначение(Отчеты.Zno);
       КонецЕсли;
       Отчеты.MoveNext();
   КонецЦикла;
   Если фЕстьОтчет = 0 Тогда
       глТрассировка("Не найдено ни одного отчета!",1);
   КонецЕсли;
   
   Для Инд = 1 по спУдалить.РазмерСписка() Цикл
       НомОтч = спУдалить.ПолучитьЗначение(Инд);
       Отчеты.Zno = НомОтч;
       Если Отчеты.EOF = 0 Тогда
           Отчеты.Delete();
           глТрассировка("Удален обработанный отчет № "+НомОтч,2);
       КонецЕсли;
   КонецЦикла;

КонецПроцедуры                  

//===========================================            
Процедура ВыгрузитьАртикулы()
   
   ЭККА = глРасшифровка.Получить("ЭККА");
   СписокТоваров = глРасшифровка.Получить("СписокТоваров");

   Попытка        
       Кассы = СоздатьОбъект("Slavich.Cashes");
   Исключение
       глТрассировка("Не удалось создать объект для доступа к ЭККА!",0);
       глТрассировка("Возможно драйвер не установлен!",0);
       Возврат;
   КонецПопытки;
   
   спПараметры = СоздатьОбъект("СписокЗначений");
   глПарсить(ЭККА.ПараметрыИнициализации,спПараметры,РазделительСтрок);
   
   СерийныйНомер = Число(спПараметры.Получить("СерийныйНомер"));
   
   Кассы.Find(СерийныйНомер);
   Если Кассы.EOF = -1 Тогда
       глТрассировка("Касса с серийным номером"+ СерийныйНомер+" не найдена!",0);
       Возврат;
   КонецЕсли;
       
   ТабТовары = Кассы.PLU;
   
   Для Инд=1 по СписокТоваров.РазмерСписка() Цикл
   
       Товар =СписокТоваров.ПолучитьЗначение(Инд);
       
       Цена = 0;Валюта = 0;
       Ошибка = "";
       Если глПолучитьЦенуТовара(Константа.РозничнаяКатегорияЦен,Товар,Товар.ЕдиницаПоУмолчанию,,Цена,Валюта,Ошибка) =0 Тогда
           глТрассировка(Ошибка,0);
           Продолжить;
       КонецЕсли;
       Цена = глПересчет(Цена,Валюта,ТекущаяДата(),Гривня,ТекущаяДата());
       Если Окр(Цена,2) = 0 Тогда
           глТрассировка("Для товара "+Товар+" задана нулевая розничная цена!" ,0);
           Продолжить;
       КонецЕсли;
       
       ТабТовары.Find(Товар.Код);
       Если ТабТовары.EOF = -1 Тогда
           ТабТовары.Code = Товар.Код;
       КонецЕсли;
       // заполним данные
       ТабТовары.Name = СокрЛП(Товар.Наименование);
       ТабТовары.Cen = Цена;
       ТабТовары.Dep = 1;
       ТабТовары.Grp = 1;
       ТабТовары.Tax = глНалоговаяГруппа(Товар.СтавкаНДС.Получить(РабочаяДата()));
       ТабТовары.Kol = 0;
       ТабТовары.FreeCen = 1;
       Если Товар.ТипТовара = Перечисление.ТипыТоваров.Штучный Тогда
           ТабТовары.FracKol = 1;
       Иначе
           ТабТовары.FracKol = 0;
       КонецЕсли;
       ТабТовары.WatchKol = 0;
       глТрассировка("Измены данные о товаре "+Товар,3);
   КонецЦикла;
   ТабТовары.Write();    
   глТрассировка("Таблица товаров записана",2);
   
   Если Вопрос("Передать информацию в пульт ? (пульт должен находится на связи с компьютером)","Да+Нет",15) = "Да" Тогда
       Кассы.Transfer();
   КонецЕсли;
       
КонецПроцедуры


//===========================================            
Процедура ПриОткрытии()
   Если ПустоеЗначение(глРасшифровка)=0 Тогда
       Параметр = глРасшифровка.Получить("Парам");
       // вызвали, как обработку - драйвер
       Если Параметр = "Инициализация" Тогда
           Инициализация();
       ИначеЕсли Параметр = "ПодключитьДрайвер" Тогда
           ИнициализацияДрайвера();
       ИначеЕсли Параметр = "ВыгрузитьАртикулы" Тогда
           ВыгрузитьАртикулы();
       ИначеЕсли Параметр = "ПечатьЧека" Тогда
           ПечатьЧека();
       ИначеЕсли Параметр = "Отчет" Тогда
           Отчет();
       КонецЕсли;
       СтатусВозврата(0);
   Иначе
       Форма.ИспользоватьЗакладки(1);
       Форма.Закладки.ДобавитьЗначение("Кассы", "Список касс");
       Форма.Закладки.ДобавитьЗначение("Пульт", "Конфигурирование пульта");
       ПриВыбореЗакладки(1,"Кассы");
       
       // открыли обработку интерактивно
       тбКонф.НоваяКолонка("Состояние","Стр",5,0,"Сост.",7);
       тбКонф.НоваяКолонка("НомКассы","Число",12,0,"Номер",15,,1);
       тбКонф.НоваяКолонка("НазвСхемы","Строка",30,0,"Тип ЭККА",25);
       тбКонф.НоваяКолонка("НомСхемы","Число",15,0,"Схема",18,,1);
       тбКонф.НоваяКолонка("КассирОсн","Число",5,0,"Кассир",10,,1);
       тбКонф.НоваяКолонка("ПарольОсн","Число",5,0,"Пароль",10,,1);
       тбКонф.НоваяКолонка("КассирПульт","Число",5,0,"Кассир",10,,1);
       тбКонф.НоваяКолонка("ПарольПульт","Число",5,0,"Пароль",10,,1);
       тбКонф.НоваяКолонка("Автопуск","Строка",3,0,"Авто",5);
       
       тбКонф.ВидимостьКолонки("НомСхемы",фВидимостьНомСхемы);
       Попытка        
           Конф = СоздатьОбъект("Slavich.Config");
       Исключение
           глТрассировка("Не удалось создать объект для доступа к конфигурации пульта!",0);
           глТрассировка("Возможно, драйвер не установлен!",0);
           СтатусВозврата(0);
           Возврат;
       КонецПопытки;
       
       спСхем = СоздатьОбъект("СписокЗначений");
       Попытка
           Состояние("Инициализация списка схем ЭККА");
           Схемы = СоздатьОбъект("Slavich.Schemas");
       Исключение
           глТрассировка("Не удалось создать объект для доступа к списку схем ЭККА!",0);
           глТрассировка("Возможно, драйвер не установлен!",0);
           СтатусВозврата(0);
           Возврат;
       КонецПопытки;
       Схемы.MoveFirst();
       Пока Схемы.EOF=0 Цикл
           спСхем.ДобавитьЗначение(Схемы.Number,Схемы.Name);
           Схемы.MoveNext();
       КонецЦикла;
       спДаНет = СоздатьОбъект("СписокЗначений");
       спДаНет.ДобавитьЗначение(-1,"Да");
       спДаНет.ДобавитьЗначение(0,"Нет");
       
       тбКассы.НоваяКолонка("НомКассы","Число",12,0,"Номер",15,,1);
       тбКассы.НоваяКолонка("Состояние","Стр",5,0,"Состояние",15);
       
       Попытка        
           Кассы = СоздатьОбъект("Slavich.Cashes");
       Исключение
           глТрассировка("Не удалось создать объект для доступа к списку касс!",0);
           глТрассировка("Возможно драйвер не установлен!",0);
           Возврат;
       КонецПопытки;
       ОбновитьКассы();
   КонецЕсли;
КонецПроцедуры    

НазваниеДрайвера = "СлавИЧ";

тётя украинка.
Какие дрова? Если для Винды, то там и так все понятно и (8) тебе может помочь. Если ДОС-овые, то только из командной строки. Чтобы потрениоваться на ККМ, неси его в ЦТО чтобы они его "якобы взяли в ремонт" и тебе можно было на нём поработать-потренироваться.

еще разновсякого бреда из ТиСдУ насовать в ветку?

пока не опустили.